package {
    import caurina.transitions.Tweener;
    import flash.events.Event;
    import flash.filters.BlurFilter;
    import flash.display.*;
    import flash.events.MouseEvent;
    import com.jacky.utils.getURL;
    import org.papervision3d.materials.MovieAssetMaterial;
    import org.papervision3d.core.math.Quaternion;
    import org.papervision3d.objects.DisplayObject3D;
    import org.papervision3d.objects.primitives.Plane;
    import org.papervision3d.core.effects.view.ReflectionView;
    import org.papervision3d.events.InteractiveScene3DEvent;
    public class PV3D_t005 extends ReflectionView {
        private var flag:Boolean;
        private var oldID:uint = 2;
        private var len:Number=0;
        private var Material0:MovieAssetMaterial = new MovieAssetMaterial("mc1");
        private var Material1:MovieAssetMaterial = new MovieAssetMaterial("mc2");
        private var Material2:MovieAssetMaterial = new MovieAssetMaterial("mc3");
        private var Material3:MovieAssetMaterial = new MovieAssetMaterial("mc4");
        private var Material4:MovieAssetMaterial = new MovieAssetMaterial("mc5");
        private var carousel:DisplayObject3D = new DisplayObject3D();
        private var tmpArr:Array=new Array();
        private var xrr:Array = new Array(-296, -158, 0, 158, 296);
        private var arr:Array = new Array(-15, -25, 0, 25, 15);
        private var zrr:Array = new Array(0, -20, -50, -20, 0);
        private var clickD:Boolean=true;
        public function PV3D_t005() {
            super(980,310,false,false);
            init();
            surfaceHeight = -250;
            this.addEventListener(Event.ENTER_FRAME,enterFrame);
        }
        private function init():void {
            for (var i:int = 0; i < 5; i++) {
                var Material:MovieAssetMaterial=this["Material"+i];
                Material.interactive=true;
                Material.allowAutoResize=true;
                Material.doubleSided=false;
                var plane:DisplayObject3D =new Plane(Material,432,259,8,8);
                viewportReflection.filters = [new BlurFilter(3,3,3)];
                viewportReflection.alpha=.2;
                //添加模糊滤镜后看起来会更逼真
                trace(Material.movie)
                
                viewport.interactive=true;

                plane.x = xrr[i];
                plane.rotationY = arr[i];
                if (i==2) {
                    plane.z=-50;
                }
                plane.id=i;
                plane.name="plan"+i;
                plane.addEventListener(InteractiveScene3DEvent.OBJECT_OVER, overHander);
                plane.addEventListener(InteractiveScene3DEvent.OBJECT_OUT, outHander);
                plane.addEventListener(InteractiveScene3DEvent.OBJECT_PRESS, pressHander);
                carousel.addChild(plane);
                //carousel相当于一个planeGroup,plane是多个的
            }
            btn.addEventListener(MouseEvent.CLICK,clickF)
            camera.z=-420;
            carousel.y=15;
            scene.addChild(carousel);
        }
        private function clickF(e){
            if(clickD){
                getURL("index-nei.html","_blank")
            }
        }
        private function overHander(e:InteractiveScene3DEvent):void {
            viewport.buttonMode=true;
        }
        private function outHander(e:InteractiveScene3DEvent):void {
            viewport.buttonMode=false;
        }
        private function preID(do3D) {

            for (var i=0; i<5; i++) {
                var tmp=i-len;
                if (tmp<0) {
                    tmp=tmp+5;
                }
                var plane=carousel.getChildByName("plan"+i);

                var tmpPlan=carousel.getChildByName("plan"+tmp);
                tmpArr[i]=tmpPlan.id;
                Tweener.addTween(plane,{rotationY:tmpPlan.rotationY,x:tmpPlan.x,z:tmpPlan.z,time:1,transition:"easeInOutQuint"});
                Tweener.addTween(btn,{alpha:1,y:292,time:2,transition:"easeInOutQuint"});
            }
            checkout();
        }
        private function checkout() {
            for (var i=0; i<5; i++) {
                var plane=carousel.getChildByName("plan"+i);
                plane.id=tmpArr[i];
                
            }
        }
        private function nextID(do3D) {
            for (var i=0; i<5; i++) {
                var tmp=i-len;
                if (tmp>4) {
                    tmp=tmp-5;
                }
                var plane=carousel.getChildByName("plan"+i);

                var tmpPlan=carousel.getChildByName("plan"+tmp);
                tmpArr[i]=tmpPlan.id;
                Tweener.addTween(plane,{rotationY:tmpPlan.rotationY,x:tmpPlan.x,z:tmpPlan.z,time:1,transition:"easeInOutQuint"});
                Tweener.addTween(btn,{alpha:1,y:292,time:2,transition:"easeInOutQuint"});
            }
            checkout();
        }
        private function pressHander(e:InteractiveScene3DEvent):void {
            //01234
            btn.alpha=0;
            btn.y=310;
            
            var plane:DisplayObject3D=e.target as DisplayObject3D;
            len=plane.id-oldID;
            if(plane.name=="plan2"){
                clickD=true;
            }else{
                clickD=false;
            }
            if (len>0) {
                preID(plane);
            } else if (len<0) {
                nextID(plane);
            }else{
                if(plane.id==2){
                    if(plane.name=="plan2"){
                        getURL("index-nei.html","_blank")
                    }
                }
            }

        }
        private function enterFrame(e:Event):void {
            singleRender();
        }
    }
}

现在PV3D处理旋转 实在是方便多了 还记得一年前 我还在AS2.0时代的时候做个这样旋转效果 忙乎了一下午
先放个以前AS2做过的套套3D

今非昔比啊，之前做的很复杂呢。不过现在PV3D里面的Quaternion我也搞不懂 知道怎么用能实现就好了。

1. package
2. {
3.     import caurina.transitions.Tweener;
4.     import flash.events.Event;
5.     import flash.filters.BlurFilter;
6.  
7.     import org.papervision3d.materials.MovieAssetMaterial;
8.     import org.papervision3d.core.math.Quaternion;
9.     import org.papervision3d.objects.DisplayObject3D;
10.     import org.papervision3d.objects.primitives.Plane;
11.     import org.papervision3d.core.effects.view.ReflectionView;
12.     import org.papervision3d.events.InteractiveScene3DEvent;
13.     public class PV3D_t005 extends ReflectionView
14.     {
15.         private var flag:Boolean;
16.         private var currentQuat:Quaternion = new Quaternion();
17.         private var targetQuat:Quaternion = new Quaternion();
18.         private var slerp:Number = 0;
19.         private const RADIUS:Number = 400;
20.         private const NUM_OF_PLANES:int = 9;
21.         private var carousel:DisplayObject3D = new DisplayObject3D();
22.         private var Material:MovieAssetMaterial=new MovieAssetMaterial("Photo1");
23.         public function PV3D_t005()
24.         {
25.             super(550,400,false,false);
26.             init();
27.             surfaceHeight = -120;
28.             this.addEventListener(Event.ENTER_FRAME,enterFrame);
29.         }
30.         private function init():void
31.         {
32.             for (var i:int = 0; i < NUM_OF_PLANES; i++) {
33.                 Material.interactive=true;
34.                 Material.allowAutoResize=true;
35.                 Material.doubleSided=true;
36.                 var plane:DisplayObject3D =new Plane(Material,100,100,4,4);
37.                 viewportReflection.filters = [new BlurFilter(3,3,3)];
38.                 //添加模糊滤镜后看起来会更逼真
39.                 viewport.interactive=true;
40.                 
41.                 plane.rotationY = 360 / NUM_OF_PLANES * i;
42.                 //以一定角度旋转每个平面，得到类似米字型
43.                 plane.moveForward(RADIUS);
44.                 //每个平面像各自前方平移上面定义的半径距离
45.                 //这两步就是组成一个环形的关键代码
46.                 
47.                 
48.             plane.addEventListener(InteractiveScene3DEvent.OBJECT_OVER, overHander);
49.             plane.addEventListener(InteractiveScene3DEvent.OBJECT_OUT, outHander);
50.             plane.addEventListener(InteractiveScene3DEvent.OBJECT_PRESS, pressHander);
51.                 carousel.addChild(plane);
52.                 //carousel相当于一个planeGroup,plane是多个的
53.             }
54.             camera.z=800;
55.             //这个一开始搞了我很久，我以为默认是1000，没想到继承ReflectionView的Z默认是-1000;
56.             scene.addChild(carousel);
57.         }
58.         private function overHander(e:InteractiveScene3DEvent):void
59.         {
60.             viewport.buttonMode=true;
61.         }
62.         private function outHander(e:InteractiveScene3DEvent):void
63.         {
64.             viewport.buttonMode=false;
65.         }
66.         private function pressHander(e:InteractiveScene3DEvent):void
67.         {
68.      var plane:DisplayObject3D=e.target as DisplayObject3D;
69.      var radians:Number = (carousel.rotationY -plane.rotationY) * Quaternion.DEGTORAD;
70.      //Quaternion.DEGTORAD是一个常数
71.      slerp = 0;
72.      currentQuat = Quaternion.createFromMatrix(carousel.transform);//复制一个3D矩阵
73.      targetQuat = Quaternion.createFromAxisAngle(0, 1, 0, radians);//x,y,z,度数
74.             
75.             //trace(plane.rotationY,Quaternion.DEGTORAD,radians)
76.  
77.         }
78.         private function enterFrame(e:Event):void
79.         {
80.             slerp += (1 - slerp) * .05;//只知道用来控制旋转速度的在0~1之间的一个变量
81.             var quat:Quaternion = Quaternion.slerp(currentQuat, targetQuat, slerp);
82.             //currentQuat和targetQuat返回的都是带有x y z w信息的东西，从初始到目标的运动
83.             carousel.transform = quat.matrix;
84.             //不断更新矩阵
85.             singleRender();
86.         }
87.     }
88. }

实例来自pv3d.org 想学好PV3D的朋友常去逛逛吧 会有收获的~

昨天帮快乐小球球同学研究的PV3D中的倒影实现。残酷天使告诉我PV3D中倒影有自带的类ReflectionView。
原文参见http://www.horidream.com/blog/?p=57
快乐小球说到的手型问题 我试了下直接在视窗上加buttonMode=true就可以了 不知道这样会有何不妥。

1. package {
2. import caurina.transitions.Tweener;
3. import flash.events.Event;
4. import org.papervision3d.materials.MovieAssetMaterial;
5. import org.papervision3d.objects.DisplayObject3D;
6. import org.papervision3d.objects.primitives.Plane;
7. import org.papervision3d.core.effects.view.ReflectionView;
8. import org.papervision3d.events.InteractiveScene3DEvent;
9. public class PV3D extends ReflectionView
10. {
11. private var flag:Boolean;
12. private var plane:DisplayObject3D;
13. private var Material:MovieAssetMaterial=new MovieAssetMaterial("Photo1");
14. public function PV3D()
15. {
16.   super(550,400,false,false);
17.   init();
18.   surfaceHeight = -120;//向下120，这个参数始终是以舞台正中间的为起点
19.   this.addEventListener(Event.ENTER_FRAME,enterFrame);
20. }
21. private function init():void{
22.   Material.interactive=true;//设置材质交互为true
23.   Material.allowAutoResize=true;//设置自适应
24.   Material.doubleSided=true;//默认是单面的。
25.   plane =new Plane(Material,285,400,4,4)
26.   plane.y=150;//如果不稍微抬高一点的话，可能会让其倒影超出舞台，或者向下120是不够滴
27.   scene.addChild(plane);
28.   viewport.interactive=true;
29.   viewport.buttonMode=true;//出现手型
30.   plane.addEventListener(InteractiveScene3DEvent.OBJECT_PRESS, pressHander);
31.   scene.addChild(plane);
32. }
33. private function pressHander(e):void
34. {
35.   Tweener.removeAllTweens();
36.   flag=!flag;
37.   if(flag)
38.   {
39.    Tweener.addTween(plane,{rotationY:720,scaleX:2,scaleY:2,time:3})
40.   }else{
41.    Tweener.addTween(plane,{rotationY:0,scaleX:1,scaleY:1,time:3})
42.   } 
43. }
44. private function enterFrame(e:Event):void{
45.   singleRender();//渲染器
46. }
47. }
48. }

1. package
2. {
3.     import org.papervision3d.core.proto.MaterialObject3D;
4.     import org.papervision3d.lights.PointLight3D;
5.     import org.papervision3d.materials.shadematerials.*;
6.     import org.papervision3d.materials.*;
7.     import org.papervision3d.materials.shaders.*;
8.     import org.papervision3d.objects.DisplayObject3D;
9.     import org.papervision3d.objects.primitives.Sphere;
10.     public class ExampleforPointLight3D extends PaperBase
11.     {
12.         private var sphere1:Sphere;
13.         private var sphere2:Sphere;
14.         private var sphere3:Sphere;
15.         private var sphere4:Sphere;
16.         private var sphereGroup:DisplayObject3D;//用一个do3d盛放这四个Sphere
17.         private static const ORBITAL_RADIUS=200;
18.         public function ExampleforPointLight3D():void
19.         {
20.             init(600,450);
21.         }
22.         override protected function init3d():void
23.         {
24.             var light:PointLight3D=new PointLight3D(true);//括号内为true表示光源可见
25.             light.x=0;
26.             light.y=300;
27.             light.z=-400;//光源的3D坐标
28.             //下面分别用到了3种阴影材质，不同的材质表现出来的效果都不一样
29.             //产生光影的方法只需要将带有光源的阴影材质放入Sphere
30.             var gouraudMaterial:MaterialObject3D = new GouraudMaterial(light, 0x6654FF, 0x060433);
31.             sphere1 = new Sphere(gouraudMaterial, 50, 10, 10);
32.             sphere1.x = ORBITAL_RADIUS;
    •             var phongMaterial:MaterialObject3D = new PhongMaterial(light, 0x6654FF, 0x060433, 150);
    •             sphere2 = new Sphere(phongMaterial, 50, 10, 10);
    •             sphere2.z = -ORBITAL_RADIUS;
    •             var cellMaterial:MaterialObject3D = new CellMaterial(light, 0x6654FF, 0x060433, 5);
    •             sphere3 = new Sphere(cellMaterial, 50, 10, 10);
    •             sphere3.z = ORBITAL_RADIUS;
33.             //如果要贴上指定位图并也要产生光影
34.             //我们就需要制作一个Shader 和一个BitmapMaterial 用ShadedMaterial来将他们混合到一起
35.             var bitmapMaterial:BitmapMaterial=new BitmapAssetMaterial("BitmapImage");
36.             var shader:Shader = new PhongShader(light, 0xFFFFFF, 0x333333, 50);
37.             var shadedMaterial:ShadedMaterial = new ShadedMaterial(bitmapMaterial, shader);
38.             sphere4 = new Sphere(shadedMaterial, 150, 20, 20);
39.             sphere4.x = -ORBITAL_RADIUS;
40.             
41.             sphereGroup = new DisplayObject3D();
42.             sphereGroup.addChild(sphere1);
43.             sphereGroup.addChild(sphere2);
44.             sphereGroup.addChild(sphere3);
45.             sphereGroup.addChild(sphere4);
46.  
47.             default_scene.addChild(sphereGroup);
48.             default_scene.addChild(light);
49.  
50.         }
51.         override protected function processFrame():void
52.         {
53.             sphere1.yaw(-8);
54.             sphere2.yaw(-8);
55.             sphere3.yaw(-8);
56.             sphere4.yaw(-8);
57.             sphereGroup.yaw(3);
58.         }
59.     }
60. }

有关PV3D方面的学习笔记 至此就告一段落了。
更多更好的PV3D的中文学习教程请参考http://www.scile.cn/  里面写的很好很全面。

先来看下这个例子，鼠标点击后翻转平面。
这里面有以下几个知识点：

1：InteractiveScene3DEvent  有了它才能使3D场景中的物体产生类似MC一样的点击事件等等。
2：Tweener 这是我常用的缓动类，当然这篇中也可以不用，不过学会用好它是很无敌的。
3：对 MovieAssetMaterial Plane的浅度了解
4：camera.focus*camera.zoom = plane.z + Math.abs(camera.z) 无敌的相机公式

1. package {
2.  import caurina.transitions.Tweener;
3.  import org.papervision3d.events.InteractiveScene3DEvent;
4.  import org.papervision3d.materials.MovieAssetMaterial;
5.  import org.papervision3d.objects.DisplayObject3D;
6.  import org.papervision3d.objects.primitives.Plane;
7.  public class Devent extends PaperBase
8.  {
9.   private var Material:MovieAssetMaterial=new MovieAssetMaterial("Photo1");//Photo1是库面板中mc的ID
10.   private var plane:DisplayObject3D; 
11.   private var flag:Boolean=false;
12.   public function Devent():void
13.   {
14.    init(700,450);
15.   }
16.   override protected function init3d():void
17.   {
18.    Material.interactive=true;//设置材质交互为true
19.    Material.allowAutoResize=true;//设置自适应
20.    Material.doubleSided=true;//默认是单面的。
21.    plane =new Plane(Material,285,400,4,4)
22. //有关plane的几个参数建议仔细阅读下API，我就犯了个不小的错误，第2，3个参数是材质的长宽，
23. //第4 5参数由于我一开始不知道他的作用 胡乱写，结果导出后它居然是占用CPU的罪魁祸首。
24. //天使给我解释后才明白，4*4相当于分成横纵的16个小切面，切面越多越精确当然也越耗CPU。
25.    default_scene.addChild(plane);
26.    viewport.interactive=true;
27. //这个一开始以为只要给材质添加上交互为true，plane是在窗口里面的，所以很显然的逻辑。
28.    default_camera.moveForward(650);//为什么要把相机向前移动，为什么参数是650.
29. //无敌的相机公式能让我们得到这个650，这样就可以使得材质渲染尺寸和我们实际需要的尺寸一样大了
30.    plane.addEventListener(InteractiveScene3DEvent.OBJECT_PRESS, pressHander);
31.   }
32.   private function pressHander(e):void
33.   {
34.    Tweener.removeAllTweens();
35.    flag=!flag;
36.    if(flag)
37.    {
38.     Tweener.addTween(plane,{rotationY:180,time:3})
39.    }else{
40.     Tweener.addTween(plane,{rotationY:0,time:3})
41.    }
42.   }
43.  }
44. }

在此要特别感谢“残酷天使”的孜孜不倦的帮助。让我在学习前沿技术的道路上坚定了信心。

这节介绍下3D键盘交互事件，实际是跟flash中一样。另外现在所有的DO3D都支持滤镜了，顺带。
通过键盘的上下左右，来控制摄像头运动

1. package
2. {
3.  import PaperBase;//导入PaperBase基础类
4.  import org.papervision3d.objects.DisplayObject3D;
5.  import org.papervision3d.objects.parsers.Collada;
6.  import flash.events.KeyboardEvent;//增加导入键盘事件包
7.  import flash.filters.*;//导入滤镜包
8.  public class Main extends PaperBase
9.  {
10.   public var cow:DisplayObject3D;//在这里cow就是do3d对象；因为Collada是继承do3d的
11.   public var filter:BlurFilter = new BlurFilter();
12.   public var wdown:Boolean = false;
13.        public var adown:Boolean = false;
14.        public var sdown:Boolean = false;
15.        public var ddown:Boolean = false;
16.   public function Main()
17.   {
18.    init(700,550);//如果你熟悉基类，这里原来的两个参数应该是默认的800*600（这不重要）
19.    stage.addEventListener(KeyboardEvent.KEY_DOWN, DownHander);
20.    stage.addEventListener(KeyboardEvent.KEY_UP, UpHander);
21.   }
22.   public function DownHander( event:KeyboardEvent ):void
23.   {
24.    switch (event.keyCode) {//w:87  a:65  s:83  d:68;上：38左：37右：39，下：40
25.     case 38 :
26.      wdown = true;
27.      break;
28.     case 37 :
29.      adown = true;
30.      break;
31.     case 40 :
32.      sdown = true;
33.      break;
34.     case 39 :
35.      ddown = true;
36.      break;
37.    }
38.   }
39.   public function UpHander( event:KeyboardEvent ):void
40.   {
41.    switch (event.keyCode) {
42.     case 38 :
43.      wdown = false;
44.      break;
45.     case 37 :
46.      adown = false;
47.      break;
48.     case 40 :
49.      sdown = false;
50.      break;
51.     case 39 :
52.      ddown = false;
53.      break;
54.    }
55.   }
56.   override protected function init3d():void
57.   {
58.    cow = new Collada("http://bogey.cn/wp-content/uploads/2008/09/cow.dae"); 
59.    cow.scale = 3;
60.    cow.moveDown(100);
61.    default_scene.addChild(cow);
62.    default_camera.target =cow;
63.    viewport.filters=[filter];//这里记住是对窗口加滤镜，你试试对奶牛直接加滤镜看看
64.   }
65.   override protected function processFrame():void
66.   {
67.    if (wdown) {
68.     default_camera.moveForward(60);//摄像机像窗口方向每次移动60；
69.    }
70.    if (sdown) {
71.     default_camera.moveBackward(60);//背离窗口方向
72.    }
73.    if (adown) {
74.     default_camera.moveLeft(15);//向左，这里我试过用yaw()函数 不过没用，
                                          //但是查了帮助，camera是支持yaw有待解决这一疑问，
75.    }
76.    if (ddown) {
77.     default_camera.moveRight(15);
78.    }
79.   }
80.  
81.  }
82. }

 用键盘上下左右控制

本节先来看个导入dae的官方例子：

1. package
2. {
3.  import PaperBase;//导入PaperBase基础类
4.  import org.papervision3d.objects.DisplayObject3D;//在基类中我们并没有导入DO3d，3D世界中DO3D是必不可少的
5.  import org.papervision3d.objects.parsers.Collada;//此类是用于3D模型导入。也就是.dae格式的
6.  public class Main extends PaperBase
7.  {
8.   public var cow:DisplayObject3D;
9.   public var distance:Number = 1000;//
10.   public function Main()
11.   {
12.    init();
13.   }
14.   override protected function init3d():void
15.   {
16.    cow = new Collada("cow.dae");
17.    cow.scale = 3;
18.    cow.moveDown(100);
19.    default_scene.addChild(cow);
20.    default_camera.target =cow;
21.   }
22.   override protected function processFrame():void
23.   {
24.    cow.yaw(1);
25.    /*default_camera.y = -(((mouseY - (stage.height / 2)) / stage.height) * 1600);
26.    default_camera.moveForward(default_camera.distanceTo(cow) - distance);
27.    cow.rotationY = -((mouseX / stage.width) * 360) ;*/试试用上这段代码
28.   }
29.  
30.  }
31. }

 default_camera.y = -(((mouseY - (stage.height/2))/stage.height) * 1600)
;//确定相机的y范围在800~~-800之间(因为我的舞台默认是800*600),
即当mouseY=0时default_camera.y=800，当mouseY=stage.height时default_camera.y=-800
   default_camera.moveForward(default_camera.distanceTo(cow) - distance);
//限定相机相对于cow乳牛模型不要移动到更远的地方
   cow.rotationY = -((mouseX / stage.width) * 360);//使用mouseX来控制cow乳牛Y方向旋转角度